Pode utilizar os seguintes exemplos em colunas calculadas de uma lista ou biblioteca. Pode utilizar exemplos que não incluem referências de colunas para especificar o valor predefinido de uma coluna.
Neste artigo
Fórmulas condicionais
Fórmulas de data e hora
Fórmulas matemáticas
Fórmulas de texto
Fórmulas condicionais
Pode utilizar as seguintes fórmulas para testar a condição de uma declaração e devolver um valor de Sim ou Não, para testar um valor alternativo, como por exemplo OK ou Não OK, ou devolver um espaço em branco ou travessão para representar um valor. nulo.
Utilize a função SE para efectuar esta comparação.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado possível) |
|---|
| 15000 | 9000 | =[Coluna1]>[Coluna2] | Coluna1 é maior do que Coluna2? (Sim) |
| 15000 | 9000 | =SE([Coluna1]<=[Coluna2], "OK", "Não OK") | Coluna1 é menor ou igual a Coluna2? (Não OK) |
Para um resultado com um valor lógico (Sim ou Não), utilize as funções E, OU e NÃO.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado possível) |
|---|
| 15 | 9 | 8 | =E([Coluna1]>[Coluna2], [Coluna1]<[Coluna3]) | 15 é maior do que 9 e menor do que 8? (Não) |
| 15 | 9 | 8 | =OU([Coluna1]>[Coluna2], [Coluna1]<[Coluna3]) | 15 é maior do que 9 e menor do que 8? (Sim) |
| 15 | 9 | 8 | =NÃO([Coluna1]+[Coluna2]=24) | 15 mais 9 não é igual a 24? (Não) |
Para um resultado que seja outro cálculo, ou outro valor diferente de Sim ou Não, utilize as funções SE, E e OU.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado possível) |
|---|
| 15 | 9 | 8 | =SE([Coluna1]=15, "OK", "Não OK") | Se o valor na Coluna1 for igual a 15, devolve "OK". (OK) |
| 15 | 9 | 8 | =SE(E([Coluna1]>[Coluna2], [Coluna1]<[Coluna3]), "OK", "Não OK") | Se 15 for maior do que 9 e menor do que 8 devolve "OK". (Não OK) |
| 15 | 9 | 8 | =SE(OU([Coluna1]>[Coluna2], [Coluna1]<[Coluna3]), "OK", "Não OK") | Se 15 for maior do que 9 ou menor do que 8 devolve "OK". (OK) |
Para apresentar um zero, efectue um cálculo simples. Para apresentar um espaço em branco ou um travessão, utilize a função SE.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado possível) |
|---|
| 10 | 10 | =[Coluna1]-[Coluna2] | Segundo número subtraído do primeiro (0) |
| 15 | 9 | =SE([Coluna1]-[Coluna2],"-",[Coluna1]-[Coluna2]) | Devolve um travessão quando o valor é zero (-) |
Para apresentar um travessão, #N/A, ou NA em vez de um valor de erro, utilize a função É.ERRO.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado possível) |
|---|
| 10 | 0 | =[Coluna1]/[Coluna2] | Resultados num erro (#DIV/0) |
| 10 | 0 | =SE(É.ERRO([Coluna1]/[Coluna2]),"NA",[Coluna1]/[Coluna2]) | Devolve NA quando o valor for um erro |
| 10 | 0 | =SE(É.ERRO([Coluna1]/[Coluna2]),"-",[Coluna1]/[Coluna2]) | Devolve um travessão quando o valor for um erro |
Parte Superior da PáginaFórmulas de data e hora
Pode utilizar as seguintes fórmulas para efectuar cálculos com base nas datas e horas, como adicionar um número de dias, meses ou anos a uma data, calcular a diferença entre duas datas e converter a hora num valor decimal.
Para adicionar um número de dias a uma data, utilize o operador (+).
Nota
Quando manipula datas, o tipo devolvido da coluna calculada tem de estar definido para Data e Hora.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 06/09/2007 | 3 | =[Coluna1]+[Coluna2] | Adiciona 3 dias a 09/06/2007 (12/06/2007) |
| 10/12/2008 | 54 | =[Coluna1]+[Coluna2] | Adiciona 54 dias a 10/12/2008 (02/02/2009) |
Para adicionar um número de meses a uma data, utilize as funções DATA, ANO, MÊS e DIA.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 09/06/07 | 3 | =DATA(ANO([Coluna1]),MÊS([Coluna1])+[Coluna2],DIA([Coluna1])) | Adiciona 3 meses a 09/06/2007 (09/09/2007) |
| 10/12/2008 | 25 | =DATA(ANO([Coluna1]),MÊS([Coluna1])+[Coluna2],DIA([Coluna1])) | Adiciona 25 meses a 10/12/2008 (10/01/2011) |
Para adicionar um número de anos a uma data, utilize as funções DATA, ANO, MÊS e DIA.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 09/06/2007 | 3 | =DATA(ANO([Coluna1])+[Coluna2],MÊS([Coluna1]),DIA([Coluna1])) | Adiciona 3 anos a 09/06/2007 (09/06/2010) |
| 10/12/2008 | 25 | =DATA(ANO([Coluna1])+[Coluna2],MÊS([Coluna1]),DIA([Coluna1])) | Adiciona 25 anos a 10/12/2008 (10/12/2033) |
Para adicionar uma combinação de dias, meses e anos a uma data, utilize as funções DATA, ANO, MÊS e DIA.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 09/06/2007 | =DATA(ANO([Coluna1])+3,MÊS([Coluna1])+1,DIA([Coluna1])+5) | Adiciona 3 anos, 1 mês e 5 dias a 09/06/2007 (14/07/2010) |
| 10/12/2008 | =DATA(ANO([Coluna1])+1,MÊS([Coluna1])+7,DIA([Coluna1])+5) | Adiciona 1 ano, 7 meses e 5 dias a 10/12/2008 (15/07/2010) |
Utilize a função DATA.SE para efectuar este cálculo.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 01-Jan-1995 | 15-Jun-1999 | =DATA.SE([Coluna1], [Coluna2],"d") | Devolve o número de dias entre duas datas (1626) |
| 01-Jan-1995 | 15-Jun-1999 | =DATA.SE([Coluna1], [Coluna2],"am") | Devolve o número de meses entre as datas, ignorando a parte do ano (5) |
| 01-Jan-1995 | 15-Jun-1999 | =DATA.SE([Coluna1], [Coluna2],"ad") | Devolve o número de dias entre as datas, ignorando a parte do ano (165) |
Para apresentar o resultado no formato de hora padrão (horas:minutos:segundos), utilize o operador de subtracção (-) e a função TEXTO. Para este método funcionar, as horas não devem exceder 24 e os minutos e segundos não podem exceder 60.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 09/06/2007 10:35 | 09/06/2007 15:30 | =TEXTO([Coluna2]-[Coluna1],"h") | Horas entre duas horas (4) |
| 09/06/2007 10:35 | 09/06/2007 15:30 | =TEXTO([Coluna2]-[Coluna1],"h:mm") | Horas e minutos entre duas horas (4:55)
|
| 09/06/2007 10:35 | 09/06/2007 15:30 | =TEXTO([Coluna2]-[Coluna1],"h:mm:ss") | Horas, minutos e segundos entre duas horas (4:55:00)
|
Para apresentar o resultado num total com base numa unidade de tempo, utilize a função INT ou HORA, MINUTO ou SEGUNDO.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 09/06/2007 10:35 | 10/06/2007 15:30 | =INT(([Coluna2]-[Coluna1])*24) | Total de horas entre duas horas (28) |
| 09/06/2007 10:35 | 10/06/2007 15:30 | =INT(([Coluna2]-[Coluna1])*1440) | Total de minutos entre duas horas (1735) |
| 09/06/2007 10:35 | 09/06/2007 15:30 | =INT(([Coluna2]-[Coluna1])*86400) | Total de segundos entre duas horas (104100) |
| 09/06/2007 10:35 | 10/06/2007 15:30 | =HORA([Coluna2]-[Coluna1]) | Horas entre duas horas, quando a diferença não excede 24 (4) |
| 09/06/2007 10:35 | 10/06/2007 15:30 | =MINUTO([Coluna2]-[Coluna1]) | Minutos entre duas horas, quando a diferença não excede 60 (55) |
| 09/06/2007 10:35 | 10/06/2007 15:30 | =SEGUNDO([Coluna2]-[Coluna1]) | Segundos entre duas horas, quando a diferença não excede 60 (0) |
Para converter horas do formato de tempo padrão para um número decimal, utilize a função INT.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 10:35 | =([Coluna1]-INT([Coluna1]))*24 | Número de horas desde 00:00 (10,583333) |
| 12:15 | =([Coluna1]-INT([Coluna1]))*24 | Número de horas desde 00:00 (12,25) |
Para converter horas de um número decimal para o formato de hora padrão (horas:minutos:segundos), utilize o operador de divisão e a função de TEXTO.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 23:58 | =TEXTO(Coluna1/24, "hh:mm:ss") | Horas, minutos e segundos desde 00:00 (00:59:55) |
| 02:06 | =TEXTO(Coluna1/24, "h:mm") | Horas e minutos desde 00:00 (00:05) |
Uma data juliana diz respeito a um formato de data que é uma combinação do ano actual e do número de dias desde o início do ano. Por exemplo, 1 de Janeiro de 2007 representa-se como 2007001 e 31 de Dezembro de 2007 representa-se como 2007365. Este formato não se baseia no calendário juliano.
Para converter uma data para uma data juliana, utilize as funções TEXTO e DATA.VALOR.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 23/06/2007 | =TEXTO([Coluna1],"aa")&TEXTO(([Coluna1]-DATA.VALOR("1/1/"& TEXTO([Coluna1],"aa"))+1),"000") | Data no formato juliano, com um ano de dois dígitos (07174) |
| 23/06/2007 | =TEXTO([Coluna1],"aaaa")&TEXTO(([Coluna1]-DATA.VALOR("1/1/"&TEXTO([Coluna1],"aa"))+1),"000") | Data no formato juliano, com um ano de quatro dígitos (2007174) |
Para converter uma data num formato juliano utilizado na astronomia, utilize a constante 2415018.50. Esta fórmula só funciona para datas depois de 01/03/1901 e, se estiver a utilizar o sistema de data 1900.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 23/06/2007 | =[Coluna1]+2415018.50 | Data no formato juliano, utilizada na astronomia (2454274.50) |
Para converter datas para texto para o dia da semana, utilize as funções TEXTO e DIA.SEMANA.
| Coluna1 | Fórmula | Descrição (resultado possível) |
|---|
| 19-Fev-2007 | =TEXTO(DIA.SEMANA([Coluna1]), "dddd") | Calcula o dia da semana para a data e devolve o nome completo do dia (segunda-feira) |
| 3-Jan-2008 | =TEXTO(DIA.SEMANA([Coluna1]), "ddd") | Calcula o dia da semana para a data e devolve o nome abreviado do dia (qui) |
Fórmulas matemáticas
Pode utilizar as seguintes fórmulas para efectuar uma variedade de cálculos matemáticos, como adicionar, subtrair, multiplicar e dividir números, calcular a média ou mediana dos números, arredondar um número e contar valores.
Para adicionar números em duas ou mais colunas numa linha, utilize o operador de adição (+) ou a função SOMA.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| 6 | 5 | 4 | =[Coluna1]+[Coluna2]+[Coluna3] | Adiciona os valores nas três primeiras colunas (15) |
| 6 | 5 | 4 | =SOMA([Coluna1],[Coluna2],[Coluna3]) | Adiciona os valores nas três primeiras colunas (15) |
| 6 | 5 | 4 | =SOMA(SE([Coluna1]>[Coluna2], [Coluna1]-[Coluna2], 10), [Coluna3]) | Se Coluna1 for maior do que Coluna2, adiciona a diferença e Coluna3. Além disso, adiciona 10 e Coluna3 (5) |
Para subtrair números em duas ou mais colunas numa linha, utilize o operador de subtracção (-) ou a função SOMA com números negativos.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| 15000 | 9000 | -8000 | =[Coluna1]-[Coluna2] | Subtrai 9000 de 15000 (6000) |
| 15000 | 9000 | -8000 | =SOMA([Coluna1], [Coluna2], [Coluna3]) | Adiciona números nas três primeiras colunas, incluindo valores negativos (16000) |
Utilize os operadores de subtracção (-) e divisão (/) e a função ABS.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 2342 | 2500 | =([Coluna2]-[Coluna1])/ABS([Coluna1]) | Alteração de percentagem (6,75% ou 0,06746) |
Para multiplicar números em duas ou mais colunas numa linha, utilize o operador de multiplicação (*) ou a função PRODUTO.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 5 | 2 | =[Coluna1]*[Coluna2] | Multiplica os números nas primeiras duas colunas (10) |
| 5 | 2 | =PRODUTO([Coluna1], [Coluna2]) | Multiplica os números nas primeiras duas colunas (10) |
| 5 | 2 | =PRODUTO([Coluna1],[Coluna2],2) | Multiplica os números nas primeiras duas colunas e o úmero 2 (20) |
Para dividir números em duas ou mais colunas numa linha, utilize o operador de divisão (/).
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 15000 | 12 | =[Coluna1]/[Coluna2] | Divide 15000 por 12 (1250) |
| 15000 | 12 | =([Coluna1]+10000)/[Coluna2] | Adiciona 15000 e 10000 e, em seguida, divide o total por 12 (2083) |
Também se dá o nome de mediana à média. Para calcular a média dos números em duas ou mais colunas numa linha, utilize a função MÉDIA.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| 6 | 5 | 4 | =MÉDIA([Coluna1], [Coluna2],[Coluna3]) | Média dos números nas primeiras três colunas (5) |
| 6 | 5 | 4 | =MÉDIA(SE([Coluna1]>[Coluna2], [Coluna1]-[Coluna2], 10), [Coluna3]) | Se Coluna1 for maior do que Coluna2, calcule a média da diferença e Coluna3. Além disso, calcule a média do valor 10 e Coluna3 (2,5) |
A mediana é o valor no centro de um intervalo ordenado de números. Utilize a função MED para calcular a mediana de um grupo de números.
| A | B | C | D | E | F | Fórmula | Descrição (resultado) |
|---|
| 10 | 7 | 9 | 27 | 0 | 4 | =MED(A, B, C, D, E, F) | Mediana dos números nas primeiras 6 colunas (8) |
Para calcular o menor ou maior número em duas ou mais colunas numa linha, utilize as funções MÍNIMO e MÁXIMO.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| 10 | 7 | 9 | =MÍNIMO([Coluna1], [Coluna2], [Coluna3]) | Menor número (7) |
| 10 | 7 | 9 | =MÁXIMO([Coluna1], [Coluna2], [Coluna3]) | Maior número (10) |
Para contar valores, utilize a função CONTAR.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| Apple | | 12/12/2007 | =CONTAR([Coluna1], [Coluna2], [Coluna3]) | Conta o número de colunas que contém valores numéricos. Exclui a data e hora, texto e valores nulos (0) |
| $12 | #DIV/0! | 1.01 | =CONTAR([Coluna1], [Coluna2], [Coluna3]) | Conta o número de colunas que contêm valores numéricos, mas exclui valores lógicos e de erro (2) |
Utilize o operador de percentagem (%) para efectuar este cálculo.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 23 | 3% | =[Coluna1]*(1+5%) | Aumenta o número na Coluna1 em 5% (24,15) |
| 23 | 3% | =[Coluna1]*(1+[Coluna2]) | Aumenta o número na Coluna1 num valor de percentagem na Coluna2: 3% (23,69) |
| 23 | 3% | =[Coluna1]*(1-[Coluna2]) | Diminui o número na Coluna1 num valor de percentagem na Coluna2: 3% (22,31) |
Utilize o operador exponencial (^) ou a função POTÊNCIA para efectuar este cálculo.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| 5 | 2 | =[Coluna1]^[Coluna2] | Calcula cinco elevado ao quadrado (25) |
| 5 | 3 | =POTÊNCIA([Coluna1], [Coluna2]) | Calcula cinco elevado ao cubo (125) |
Para arredondar um número, utilize a função ARRED.PARA.CIMA, ÍMPAR ou PAR.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 20,3 | =ARRED.PARA.CIMA([Coluna1],0) | Arredonda para cima 20,3 para o número inteiro mais próximo (21) |
| -5,9 | =ARRED.PARA.CIMA([Coluna1],0) | Arredonda para cima -5,9 para o número inteiro mais próximo (-5) |
| 12,5493 | =ARRED.PARA.CIMA([Coluna1]0,2) | Arredonda para cima 12,5493 para a centena, com duas casas decimais mais próxima (12.55) |
| 20,3 | =PAR([Coluna1]) | Arredonda para cima 20,3 para o número par mais próximo (22) |
| 20,3 | =ÍMPAR([Coluna1]) | Arredonda para cima 20,3 para o número ímpar mais próximo (21) |
Para arredondar para baixo um número, utilize a função ARRED.PARA.BAIXO.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 20,3 | =ARRED.PARA.BAIXO([Coluna1],0) | Arredonda para baixo 20,3 para o número inteiro mais próximo (20) |
| -5,9 | =ARRED.PARA.BAIXO([Coluna1],0) | Arredonda para baixo -5,9 para o número inteiro mais próximo (-6) |
| 12,5493 | =ARRED.PARA.BAIXO([Coluna1],2) | Arredonda para baixo 12,5493 para a centena, com duas casas decimais mais próxima (12,54) |
Para arredondar um número para o número ou fracção mais próximo, utilize a função ARRED.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 20,3 | =ARRED([Coluna1],0) | Arredonda para baixo 20,3, porque a parte da fracção é menor do que 0,5 (20) |
| 5,9 | =ARRED([Coluna1],0) | Arredonda para cima 5,9, porque a parte da fracção é maior do que 0,5 (6) |
| -5,9 | =ARRED([Coluna1],0) | Arredonda para baixo -5,9, porque a parte da fracção é menor do que -0,5 (-6) |
| 1,25 | =ARRED([Coluna1], 1) | Arredonda o número para a décima parte mais próxima (uma casa decimal). Como a parte a ser arredondada é 0,05 ou maior, o número é arredondado para cima (resultado: 1,3) |
| 30,452 | =ARRED([Coluna1], 2) | Arredonda o número para a centésima parte mais próxima (duas casas decimais). Como a parte a ser arredondada é 0,002, é menor do que 0,005, o número é arredondado para baixo (resultado: 30,45) |
Para arredondar um número para o dígito significativo acima de 0, utilize as funções ARRED, ARRED.PARA.CIMA, ARRED.PARA.BAIXO, INT e NÚM.CARACT.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| 5492820 | =ARRED([Coluna1],3-NÚM.CARACT(INT([Coluna1]))) | Arredonda o número para 3 dígitos significativos (5490000) |
| 22230 | =ARRED.PARA.BAIXO([Coluna1],3-NÚM.CARACT(INT([Coluna1]))) | Arredonda para baixo o número inferior para 3 dígitos significativos (22200) |
| 5492820 | =ARRED.PARA.CIMA([Coluna1], 5-NÚM.CARACT(INT([Coluna1]))) | Arredonda para cima o número mais alto para 5 dígitos significativos (5492900) |
Fórmulas de texto
Pode utilizar as seguintes fórmulas para manipular texto, como combinar ou concatenar os valores de múltiplas colunas, comparar o conteúdo das colunas, remover os caracteres ou espaços e repetir caracteres.
Para alterar as maiúsculas/minúsculas do texto, utilize as funções MAIÚSCULAS, MINÚSCULAS ou INICIAL.MAIÚSCULA.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| inês Vieira | =MAIÚSCULAS([Coluna1]) | Altera o texto para maiúsculas (INÊS VIEIRA) |
| inês Vieira | =MINÚSCULAS([Coluna1]) | Altera o texto para minúsculas (INÊS VIEIRA) |
| inês Vieira | =INICIAL.MAIÚSCULA([Coluna1]) | Altera o texto para maiúscula inicial (INÊS VIEIRA) |
Para combinar o nome e apelido, utilize o operador E comercial (&) ou a função CONCATENAR.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| Carlos | Carvalho | =[Coluna1]&[Coluna2] | Combina as duas cadeias (CarlosCarvalho) |
| Carlos | Carvalho | =[Coluna1]&" "&[Coluna2] | Combina duas cadeias, separadas por um espaço (Carlos Carvalho) |
| Carlos | Carvalho | =[Coluna2]&", "&[Coluna1] | Combina duas cadeias, separadas por uma vírgula e um espaço (Carvalho, Carlos) |
| Carlos | Carvalho | =CONCATENAR([Coluna2], ",", [Coluna1]) | Combina as duas cadeias, separadas por uma vírgula (Carvalho,Carlos) |
Para combinar texto e números, utilize a função CONCATENAR, o operador E comercial (&) ou a função TEXTO e o operador E comercial.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| Sousa | 28 | =[Coluna1]&" vendeu "&[Coluna2]&" unidades." | Combina o conteúdo acima numa frase (Sousa vendeu 28 unidades.) |
| Dinis | 40% | =[Coluna1]&" vendeu "&TEXTO([Coluna2],"0%")&" das vendas totais." | Combina o conteúdo acima numa frase (Dinis vendeu 40% das vendas totais.)
Nota
A função TEXTO anexa o valor formatado da Coluna2, em vez do valor subjacente, que é 0,4. |
| Sousa | 28 | =CONCATENAR([Coluna1]," vendeu ",[Coluna2]," unidades.") | Combina o conteúdo acima numa frase (Sousa vendeu 28 unidades.) |
Para combinar texto com uma data ou hora, utilize a função TEXTO e o operador E comercial (&).
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado) |
|---|
| Data da Factura | 05-Jun-2007 | ="Data da declaração: "&TEXTO([Coluna2], "d-mmm-aaaa") | Combina texto com uma data (Data da declaração: 05-Jun-2007) |
| Data da Factura | 05-Jun-2007 | =[Coluna1]&" "&TEXTO([Coluna2], "mmm-dd-aaaa") | Combina texto e data de diferentes colunas numa coluna (Data da Factura Jun-05-2007) |
Para comparar uma coluna com outra coluna ou uma lista de valores, utilize as funções EXACTO e OU.
| Coluna1 | Coluna2 | Fórmula | Descrição (resultado possível) |
|---|
| BD122 | BD123 | =EXACTO([Coluna1],[Coluna2]) | Compara conteúdo das primeiras duas colunas (Não)
|
| BD122 | BD123 | =EXACTO([Coluna1], "BD122") | Compara conteúdo da Coluna1 e a cadeia "BD122" (Sim)
|
Para verificar se um valor da coluna ou uma parte do valor corresponde a texto específico, utilize as funções SE, LOCALIZAR, PROCURAR e É.NÚMERO.
| Coluna1 | Fórmula | Descrição (resultado possível) |
|---|
| Vieira | =SE([Coluna1]="Vieira", "OK", "Não OK") | Verifica para ver se Coluna1 é Vieira (OK) |
| Vieira | =SE(É.NÚMERO(LOCALIZAR("v",[Coluna1])), "OK", "Não OK") | Verifica para ver se Coluna1 contém a letra v (OK) |
| BD123 | =É.NÚM(LOCALIZAR("BD",[Coluna1])) | Verifica para ver se Coluna1 contém BD (Sim) |
Para contar colunas preenchidas, utilize a função CONTAR.VAL.
| Coluna1 | Coluna2 | Coluna3 | Fórmula | Descrição (resultado) |
|---|
| Vendas | 19 | | =CONTAR.VAL([Coluna1], [Coluna2]) | Conta o número de colunas preenchidas (2)
|
| Vendas | 19 | | =CONTAR.VAL([Coluna1], [Coluna2], [Coluna3]) | Conta o número de colunas preenchidas (2)
|
Para remover caracteres do texto, utilize as funções NÚM.CARACT, ESQUERDA e DIREITA.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| Vitamina A | =ESQUERDA([Coluna1],NÚM.CARACT([Coluna1])-2) | Devolve 7 (9-2) caracteres, começando da esquerda (Vitamin)
|
| Vitamina B1 | =DIREITA([Coluna1], NÚM.CARACT([Coluna1])-8) | Devolve 2 (10-8) caracteres, começando da direita (B1) |
Para remover espaços de uma coluna, utilize a função COMPACTAR.
| Coluna1 | Fórmula | Descrição (resultado) |
|---|
| Quem está? | =COMPACTAR([Coluna1]) | Remove os espaços do início e fim (Quem está?)
|
Para repetir um carácter numa coluna, utilize a função REPETIR.
| Fórmula | Descrição (resultado) |
|---|
| =REPETIR(".",3) | Repete um ponto final 3 vezes (...) |
| =REPETIR("-",10) | Repete um travessão 10 vezes (----------) |